【Oracle】ランダムなテストデータを作ってみよう！(顧客データ)

今回は、SQLでランダムなテストデータを作ってみようということで、顧客データを想定してサンプルコードを作成してみました。

ランダムなテストデータを作ってみよう！

顧客テーブルの作成

-- 顧客テーブルの作成
CREATE TABLE customers (
    customer_id NUMBER PRIMARY KEY,　　　-- 顧客ID (プライマリキー)
    first_name VARCHAR2(50),　　　-- 名
    last_name VARCHAR2(50),　　　-- 姓
    email VARCHAR2(100),　　　　-- メールアドレス
    phone VARCHAR2(15),　　　-- 電話番号
    address VARCHAR2(200), 　　　-- 住所
    city VARCHAR2(100),　　　-- 都市
    postal_code VARCHAR2(10)　　　-- 郵便番号
);

文字列を区切り文字で分割する関数

-- 文字列を区切り文字で分割し、リストとして返す関数の作成
CREATE OR REPLACE FUNCTION split_string(
    p_string IN VARCHAR2,   -- 分割対象の文字列
    p_delimiter IN VARCHAR2 := ','    -- 区切り文字 (デフォルトはカンマ)
) RETURN SYS.ODCIVARCHAR2LIST IS
    l_string VARCHAR2(32767) := p_string || p_delimiter;   -- 区切り文字を追加
    l_list SYS.ODCIVARCHAR2LIST := SYS.ODCIVARCHAR2LIST();   -- 結果リストの初期化
    l_pos PLS_INTEGER;   -- 区切り文字の位置
    l_index PLS_INTEGER := 1;   -- 現在の位置
BEGIN
    LOOP
        l_pos := INSTR(l_string, p_delimiter, l_index);   -- 次の区切り文字の位置を取得
        EXIT WHEN l_pos = 0;   -- 区切り文字が見つからない場合、ループを終了
        l_list.EXTEND;  -- リストのサイズを1つ拡張
        l_list(l_list.COUNT) := SUBSTR(l_string, l_index, l_pos - l_index);   -- 区切り文字までの部分文字列をリストに追加
        l_index := l_pos + LENGTH(p_delimiter);  -- 次の開始位置を設定
    END LOOP;
    RETURN l_list;  -- 結果リストを返す
END;

ランダムなデータの作成

-- ランダムな名前を取得する関数の作成
CREATE OR REPLACE FUNCTION get_random_first_name RETURN VARCHAR2 IS
    first_names SYS.ODCIVARCHAR2LIST := split_string('Taro,Jiro,Hanako,Kenichi,Mayumi,Sachiko,Ichiro,Jiro,Yoshi,Saburo');
BEGIN
    RETURN first_names(TRUNC(DBMS_RANDOM.VALUE(1, first_names.COUNT + 1)));  -- ランダムに選ばれた名前を返す
END;

-- ランダムな苗字を取得する関数の作成
CREATE OR REPLACE FUNCTION get_random_last_name RETURN VARCHAR2 IS
    last_names SYS.ODCIVARCHAR2LIST := split_string('Sato,Suzuki,Takahashi,Tanaka,Ito,Watanabe,Yamamoto,Nakamura,Kobayashi,Kato');
BEGIN
    RETURN last_names(TRUNC(DBMS_RANDOM.VALUE(1, last_names.COUNT + 1)));  -- ランダムに選ばれた苗字を返す
END;

-- ランダムなメールアドレスを生成する関数の作成
CREATE OR REPLACE FUNCTION get_random_email(
    p_first_name VARCHAR2,
    p_last_name VARCHAR2
) RETURN VARCHAR2 IS
BEGIN
    RETURN LOWER(p_first_name || '.' || p_last_name || '@gmail.com');
END;

-- ランダムな電話番号を生成する関数の作成
CREATE OR REPLACE FUNCTION get_random_phone RETURN VARCHAR2 IS
BEGIN
    RETURN '080' || TO_CHAR(TRUNC(DBMS_RANDOM.VALUE(10000000, 99999999)));  -- ランダムな電話番号を返す
END;

-- ランダムな住所を生成する関数の作成
CREATE OR REPLACE FUNCTION get_random_address RETURN VARCHAR2 IS
    streets SYS.ODCIVARCHAR2LIST := split_string('中央区,新宿区,渋谷区,品川区,港区,世田谷区,目黒区,江東区,杉並区,大田区');
BEGIN
    RETURN streets(TRUNC(DBMS_RANDOM.VALUE(1, streets.COUNT + 1))) || TRUNC(DBMS_RANDOM.VALUE(1, 9)) || '丁目';  -- ランダムな住所を返す
END;

-- ランダムな都市名を取得する関数の作成
CREATE OR REPLACE FUNCTION get_random_city RETURN VARCHAR2 IS
    cities SYS.ODCIVARCHAR2LIST := split_string('東京都');
BEGIN
    RETURN cities(TRUNC(DBMS_RANDOM.VALUE(1, cities.COUNT + 1)));  -- ランダムな都市名を返す
END;

-- ランダムな郵便番号を生成する関数の作成
CREATE OR REPLACE FUNCTION get_random_postal_code RETURN VARCHAR2 IS
BEGIN
    -- 最初の3文字を100に固定し、残りの4文字をランダムに生成
    RETURN '100' || TO_CHAR(TRUNC(DBMS_RANDOM.VALUE(1000, 9999)), 'FM0000');
END;

ランダムなデータをテーブルに追加

-- ランダムなデータをテーブルに追加
BEGIN
    FOR i IN 1..50 LOOP  -- 50件のデータを追加
        DECLARE
            v_first_name VARCHAR2(50);
            v_last_name VARCHAR2(50);
        BEGIN
            -- ランダムな名前を取得
            v_first_name := get_random_first_name();
            v_last_name := get_random_last_name();
            -- データを挿入
            INSERT INTO customers (
                customer_id,  -- 顧客ID
                first_name,  -- 名
                last_name,   -- 姓
                email,  -- メールアドレス
                phone,  -- 電話番号
                address,  -- 住所
                city,   -- 都市
                postal_code   -- 郵便番号
            ) VALUES (
                i,  -- インデックスを顧客IDとして使用
                v_first_name,  -- ランダムな名
                v_last_name,   -- ランダムな姓
                get_random_email(v_first_name, v_last_name),  -- ランダムなメールアドレスを生成
                get_random_phone(),       -- ランダムな電話番号を生成
                get_random_address(),     -- ランダムな住所を生成
                get_random_city(),        -- ランダムな都市名を取得
                get_random_postal_code()  -- ランダムな郵便番号を生成
            );
        END;
    END LOOP;
    COMMIT;  -- トランザクションをコミット
END;

作成したデータを確認

SELECT
  customer_id AS "顧客ID ",
  first_name AS "名",
  last_name AS "性",
  email AS "メールアドレス",
  -- 電話番号 xxx-xxxx-xxxx
　 SUBSTR(phone, 1, 3) || '-' || SUBSTR(phone, 4, 4) || '-' || SUBSTR(phone, 8, 4) AS "電話番号",
  address AS "住所",
  city AS "都市",
  -- 郵便番号 xxx-xxxx 
  SUBSTR(postal_code, 1, 3) || '-' || SUBSTR(postal_code, 4, 4) AS "郵便番号"
FROM
  customers;

まとめ

いかがでしたか？それっぽいデータが出来上がったと思います。ぜひ、サンプルコードを使って手を動かしながら色々試してみてください！